Danke Ihr beiden ...
... aber das (oder so ähnlich hatte ich probiert, aber darauf reagiert die Anwendung überhaupt nicht.
Nur das vorherige Umstellen der Auflösung (durch Multires) 'bringt' etwas. Hier mal die Batch, vielleicht reden wir auch irgendwie aneinander vorbei:
[MENTION=41345]Echo[/MENTION] off
: DOIT
setlocal
call :initEnv
call :getOptions %*
call :findJava
if "%javaDir%" == "" goto :NOJRE
if "%java6Dir%" == "" goto :NOJRE16
if "%javaExe%" == "" goto :WRONGJRE16
set javaOpts=%javaOpts% -splash
eluxeSplashScreen.png
goto :LAUNCH
:LAUNCH
echo INFO: Using Java version %javaVer% from "%java6Dir%"
if %verbose% == 1 (
echo. >> %logfile%
echo ENVIRONMENT: >> %logfile%
echo date time = %date% %time% >> %logfile%
echo logfile = %logfile% >> %logfile%
echo java6Dir = "%java6Dir%" >> %logfile%
echo javaExe = "%javaExe%" >> %logfile%
echo javawExe = "%javawExe%" >> %logfile%
echo javaMun = %javaMun% >> %logfile%
echo javaVer = %javaVer% >> %logfile%
)
if %findJava% == 1 goto :eof
goto :RUN_%barrVer%
:RUN_1.4.11
if %verbose% == 1 (
echo CMDLINE: start "%javaExe%" %javaOpts% -jar Glucofacts.jar %param% >> %logfile%
) else (
echo %date% %time% - CMDLINE: start "%javaExe%" %javaOpts% -jar Glucofacts.jar %param% >> %logfile%
)
start "GLUCOFACTS Deluxe" "%javaExe%" %javaOpts% -jar Glucofacts.jar %param%
goto :RUN_CONTINUED
:RUN_Latest
:RUN_1.4.12
if %verbose% == 1 (
echo CMDLINE: start "%javawExe%" %javaOpts% -jar Glucofacts.jar %param% >> %logfile%
) else (
echo %date% %time% - CMDLINE: start "%javawExe%" %javaOpts% -jar Glucofacts.jar %param% >> %logfile%
)
if "%param%"=="Apollo-Barracuda" (
cd "GLUCOFACTS Deluxe"
)
start "GLUCOFACTS Deluxe" "%javawExe%" %javaOpts% -jar Glucofacts.jar %param%
goto :RUN_CONTINUED
:RUN_CONTINUED
if errorlevel 1 goto :JAVAERROR
del %logfile%
goto :EXIT
:initEnv
set debug=0
set verbose=0
set exitCmd=exit
set barrVer=Latest
set param=PC-Barracuda
set logfile="%USERPROFILE%\BarracudaLog.txt"
set javaDir=
set java6Dir=
set javaExe=
set javaMun=-1
set javaVer=
set javaOpts=-XX:MaxPermSize=128m -Xms128m -Xmx512m -Dsun.locale.formatasdefault=true
set useJava=0
set findJava=0
goto :eof
:findJava
set javaExe=
call :getJavaExe
if not "%javaExe%" == "" goto :eof
call :findJavaExe
if not "%javaExe%" == "" goto :eof
call :findJava6Exe
goto :eof
:getJavaExe
call :inPath java.exe
if %inpath% == "" goto :eof
call :checkJavaVer %inpath%
goto :eof
:getJavaVer exe version
::
:: java version syntax <Major>.<Minor>.<Maintenance>_<Update>
::
:: get and cleanup the version, which may actually be a directory name (eg. jre1.6.0, jre1.6.0_17 jdk1.6.0_011)
set ver=%~2
set ver=%ver:jdk=%
set ver=%ver:jre=%
if %debug% == 1 (
echo DEBUG: found java version %ver% located in %1
if %verbose% == 1 (
echo DEBUG: found java version %ver% located in %1 >> %logfile%
)
)
set ver2=%ver:.= %
call :getJavaVersions %ver2:_= %
set vern=%major%%minor%
if %vern% LSS 16 goto :eof
if %vern% EQU 16 (
if %updat% LSS 17 goto :eof
)
if %updat% GTR 0 (
if "%updat:~0,1%"=="0" SET updat=%updat:~1%
)
set /a m_u=1000 * %maint% + %updat%
if %m_u% LSS %javaMun% goto :eof
set javaMun=%m_u%
set java6Dir=%~dp1
set javaVer=%ver%
set javaExe=%~1
set javawExe=%~dp1%~n1w.exe
if %vern% GTR 17 (
set javaOpts=-XX:MaxMetaspaceSize=128m -Xms128m -Xmx512m -Dsun.locale.formatasdefault=true
)
if %useJava% == 1 set javawExe=%javaExe%
if "%javaDir%" == "" set javaDir=%java6Dir%
if %debug% == 1 (
echo DEBUG: like java version %javaVer% located in "%java6Dir%"
if %verbose% == 1 (
echo DEBUG: like java version %javaVer% located in "%java6Dir%" >> %logfile%
)
)
goto :eof
:getJavaVersions <Major> <Minor> <Maintenance> <Update>
set major=%1
set minor=%2
set maint=%3
set updat=0
if not "%4" == "" set updat=%4
goto :eof
:findJavaExe
call :findJava6Exe "%ProgramFiles%\Java\jre6"
call :checkJavaDir "%ProgramFiles%\Java"
call :findJava6Exe "%ProgramFiles(x86)%\Java\jre6"
call :checkJavaDir "%ProgramFiles(x86)%\Java"
call :findJava6Exe "%ProgramFiles%\Java\jre7"
call :checkJavaDir "%ProgramFiles%\Java"
call :findJava6Exe "%ProgramFiles(x86)%\Java\jre7"
call :checkJavaDir "%ProgramFiles(x86)%\Java"
goto :eof
:findJava6Exe "<dirName>"
if not exist "%~1" goto :eof
call :checkJavaVer "%~1\bin\java.exe"
goto :eof
:checkJavaDir "<dirName>"
for /D %%n in ("%~1"\jre1.* "%~1"\jdk1.*) do call :javaSupported "%%n"
goto :eof
arseJavaVer exe java version "<version>"
if not "%2" == "java" goto :eof
if not "%3" == "version" goto :eof
call :getJavaVer "%~1" %4
goto :eof
:javaSupported dir
call :getJavaVer "%~1\bin\java.exe" %~nx1
goto :eof
:inPath
set inpath="%~$PATH:1"
if not %inpath% == "" goto :eof
if "%PROCESSOR_ARCHITECTURE%" == "x86" goto :eof
set PATH="%PATH%;%SystemRoot%\SysWOW64"
set inpath="%~$PATH:1"
goto :eof
:checkJavaVer
"%~1" -version > %temp%\javaver.txt 2>&1
:: example output of: java -version
:: java version "1.6.0_10"
:: Java(TM) SE Runtime Environment (build 1.6.0_10-b33)
:: Java HotSpot(TM) Client VM (build 11.0-b15, mixed mode, sharing)
::
for /F "tokens=1-3" %%n in (%temp%\javaver.txt) do call
arseJavaVer "%~1" %%n %%o %%p
goto :eof
:getOptions
if "%1" == "" goto :eof
set a=%1
if not "%a:~0,1%" == "-" goto :eof
if "%a%" == "-debug" set debug=1
if "%a%" == "-echoon" echo on
if "%a%" == "-verbose" set verbose=1
if "%a%" == "-noexit" set exitCmd=echo DONE
if "%a%" == "-pcbarr" set param=PC-Barracuda
if "%a%" == "-abarr" set param=Apollo-Barracuda
if "%a%" == "-1.4.11" set barrVer=1.4.11
if "%a%" == "-1.4.12" set barrVer=1.4.12
if "%a%" == "-jopt" shift & set javaOpt=%javaOpt% %1
if "%a%" == "-java" set useJava=1
if "%a%" == "-findjava" set findJava=1 & set debug=1 & set exitCmd=echo DONE & set verbose=1
shift
goto :getOptions
:toURL file
set escd=
call :esc20 %*
set url=file:///%escd:\=/%
goto :eof
:esc20
rem echo esc20 -- 1 = %1
rem pause
if "%1" == "" goto :eof
if "%escd%" == "" (
set escd=%1
) else (
set escd=%escd%%%20%1
)
rem echo escd=%escd%
shift
goto :esc20
:NOJRE
echo **** ERROR: No JRE Found! Barracuda needs JRE1.6
set fn=messageFS.html
goto ERROR
:NOJRE16
echo **** ERROR: No JRE 1.6 Found in the System. Barracuda needs JRE1.6
set fn=messageFS.html
goto ERROR
:WRONGJRE16
echo **** ERROR: Incompatible JRE 1.6 Found in the System. Barracuda needs JRE1.6.0_17 or better.
set fn=messageFS.html
goto ERROR
:JAVAERROR
echo **** ERROR: Unable to invoke Java successfully.
set fn=javaErrorFS.html
goto :ERROR
:ERROR
call :toURL %~dp0html\%fn%
if "%param%"=="Apollo-Barracuda" start %url%
echo ENVIRONMENT:
echo errorlevel = %errorlevel%
echo java6Dir = %java6Dir%
echo javaExe = %javaExe%
echo javawExe = %javawExe%
echo javaMun = %javaMun%
echo javaVer = %javaVer%
echo.
if exist %logfile% (
pause
echo CONTENTS: %logfile%
echo.
type %logfile%
echo.
echo END CONTENTS
)
pause
goto :EXIT
:EXIT
%exitCmd%
goto :eof