Lightroom Entwicklungseinstellungen per Tastatur stuerern

[Keeny]

Lightroom Entwicklungseinstellungen per Tastatur steuern

Bin heute auf >ein Skript< für www.AutoHotKey.com zum steuern von Belichtung, Kontrast, Fill Light, Farbtemperatur und Navigation im Gordon McKinney's Photography Blog
gestolpert.

Es ist vergleichbar mit RPG KEY Edit'ER,
das kommerziell vertrieben wird (Kostenpunkt $235.00) Angeblich kann man damit 2000 Fotos in 3 Stunde editieren

Getestet hab ich es noch nicht, bin immer noch mit Programmieren meier Preh Kassentastatur beschäftigt. Nähere Infos findet ihr >hier<:winkgrin:

Viel Spass beim Ausprobier:hallo:


P.S.Ich würde mich (höchstwahrscheinlich auch andere Lightroom User) sehr freuen, wenn jemand das Script in ausführbare EXe-Datei umwandelt und hier postet.

Klicken zum Weiterlesen...

 

[Keeny]

Okay,
heute etwas Zeit gefunden und mit dem Script etwas rum gespielt.
Erst musste ich ihm bisschen Deutsch beibringen.

..........jetzt läuft`s auch mit deutscher Version des Lightrom`s.

; ----------------------------------------
;
; Gordon's Lightroom 2.0 Shortcuts Aug-22 2008
; www.night-ray.com
;
;
; Use numpad to perform certain develop and library functions.
; This effectively disables the number pad for digit entry
; (except 5 and 0) please use the main keyboard instead.
;
; NOTE: NumLock must be ON... otherwise this will not work.
;
;
; Left/Right    - Prev or Next photo
; Up/Down       - Exposure
; Minus/Plus    - Fill Light
; Page Up/Dn    - Contrast
; Home/End      - Color Temperature
; Div/Mult      - Color Tint
; Enter         - Paste Previous
; Dot (Delete)  - AutoTone
;
; F9  Library Module
; F10 Develop Module
; F11 Slideshow Module
; F12 Web Module
;
SetTitleMatchMode,2
;
#IfWinActive, Adobe Photoshop Lightroom
  F9::Send  ^!1
  F10::Send ^!2
  F11::Send ^!3
  F12::Send ^!5
#IfWinActive
;
; *** DEVELOP SHORTCUTS ***
;
#IfWinActive, Adobe Photoshop Lightroom - Entwickeln
  numpad4::     Send ^{Left}
  numpad6::     Send ^{Right}
  numpad8::     lrdAdd(09)
  numpad2::     lrdSub(09)
  NumpadAdd::   lrdAdd(11)
  NumpadSub::   lrdSub(11)
  numpad9::     lrdAdd(14)
  numpad3::     lrdSub(14)
  numpad7::     lrdAdd(04)
  numpad1::     lrdSub(04)
  NumPadMult::  lrdAdd(05)
  NumPadDiv:: lrdSub(05)
  NumPadDot:: Send ^!u
  NumPadEnter:: Send ^!v
  ;
  lrdAdd(delta) {
   instance := lrGetControl( Static, 6, "Behandlung:", delta )
   ControlClick, Static%instance%
   Send {+}
  }
      ;
      lrdSub(delta) {
       instance := lrGetControl( Static, 6, "Behandlung:", delta )
       ControlClick, Static%instance%
       Send {-}
      }
#IfWinActive
;
; *** LIBRARY SHORTCUTS ***
;
#IfWinActive, Adobe Photoshop Lightroom - Bibliothek
  numpad4::    Send ^{Left}
  numpad6::    Send ^{Right}
  numpad8::    lrlClick(03)
  numpad2::    lrlClick(02)
  NumpadAdd::  lrlClick(11)
  NumpadSub::  lrlClick(10)
  numpad9::    lrlClick(23)
  numpad3::    lrlClick(22)
  numpad7::    lrlClick(-6)
  numpad1::    lrlClick(-7)
  NumPadMult:: lrlClick(-2)
  NumPadDiv:: lrlClick(-3)
  NumPadDot:: Send ^!u
  NumPadEnter::Send ^!v
  ;
  lrlClick(delta) {
   instance := lrGetControl( Button, 6, "Autom. Farbton", delta )
   ControlSend, Button%instance%, {SPACE}, ahk_class AgWinMainFrame
  }
#IfWinActive
;
; Fetch the Control Instance using Type, Title, and Instance Delta
;
lrGetControl( type, typeLen, title, delta ) {
  global lrLastTitle, lrLastCBase, lrLastCache
  ;
  if (lrLastTitle = title and lrLastCache > A_TickCount )
  {
    ; Cached! Saves time.
    return lrLastCBase + delta
  }
  else
  {
    WinGet, ActiveControlList, ControlList, ahk_class AgWinMainFrame
    Loop, Parse, ActiveControlList, `n
    {
      IfInString, A_LoopField, %type%
      {
        ControlGetText, text, %A_LoopField%
        IfInString, text, %title%
        {
          StringMid, controlbase, A_LoopField, typeLen+1
          lrLastTitle := title
          lrLastCBase := controlbase
          lrLastCache := A_TickCount + (120*1000)
          return controlbase + delta
        }
      }
    }
  }
  return 999999
}
;
; End
; ----------------------------------------

Mit den Tasten F9 bis F12 navigiert man durch verschiedene Module, also von Bibliothek bis hin zu Web-Modul.

Für diejenige, die auf das AutoHotKey Programm verzichten wollen, hab ich eine EXE-Konvertierung angefertigt.
>Download EXE Version<